#declare BenchTexture =	
texture {
	pigment {
		wood
		turbulence 0.05
		color_map {
        		[0.0 rgb <0.93, 0.71, 0.53>*.15+Gray40]
        		[0.8 rgb <0.98, 0.81, 0.60>*.15+Gray40]
		        [0.8 rgb <0.60, 0.33, 0.27>*.15+Gray20]
        		[1.0 rgb <0.70, 0.60, 0.23>*.15+Gray30]
		}
	}
/*	normal {
		wood .03
		turbulence .05
		scale 3
	}*/
	normal {
		bumps .15
		scale 3
	}
	finish {
		diffuse .3
		specular .002
		roughness .1
	}
	
	rotate x*90 // centre on the y-axis
	scale 1

	translate <200,200,200>
	rotate z*88
//	rotate y*90	
}
texture {
	pigment {
		agate
		turbulence 0.25
		color_map {
        		[0.0 rgbf <1,1,1,1>]
        		[0.2 rgbf <1,1,1,1>]
        		[0.5 rgbf .9] //<.8,.8,.8,.8>]
        		[0.7 rgbf .9] //<.8,.8,.8,.8>]
        		[1.0 rgbf <1,1,1,1>]
		}
	}
	scale 400
	translate <100,1000,100>
}
/*texture {
	pigment {
		bozo
		turbulence 0.25
		color_map {
        		[0.0 rgbf <1,1,1,1>]
        		[0.05 colour Brown*.2]
        		[0.1 rgbf <1,1,1,1>]
        		[1.0 rgbf <1,1,1,1>]
		}
	}
	scale 40
}*/
#declare bench = union {
	difference {
		union {
			box {
				<-80,0,-12>		//Leg 1   1/2
				<-77,60,-1>
			}
			box {
				<-80,0,1>
				<-77,60,12>
			}
			box {
				<80,0,-12>		// Leg 2    1/2
				<77,60,-1>
			}
			box {
				<80,0,1>
				<77,60,12>
			}
			texture {
				BenchTexture
				rotate z*88
			}
			texture {
				pigment {
					gradient y
					turbulence .35
					color_map {
//						[0.0 colour ForestGreen*.5]
//						[0.11 colour ForestGreen*.5]
//						[.41 rgbf 1]
//						[1.0 rgbf 1]
						[0.0 rgb <.7,1,.6>]
						[0.11 rgb <.7,1,.6>]
						[.41 rgbf 1]
						[1.0 rgbf 1]
					}
					scale 70
				}
				normal {
					bumps .55
					scale 1
				}
				finish {
					diffuse .4
					specular .01
					roughness 1
				}
				translate <400,-5,400>
				rotate y*-2
			}

		}
		union {
			box {
				<78,53,-12>
				<-78,50,-1>
			}
			box {
				<78,53,1>
				<-78,50,12>
			}
			scale 1.01
		}
	}
	box {
		<78,53,-12>
		<-78,50,-1>
		texture {
			BenchTexture
		}
	}
	box {
		<78,53,1>
		<-78,50,12>
		texture {
			BenchTexture
			rotate y*180
			translate <30,30,30>
		}
	}
#declare plaquetexture = texture {
	Brass_Texture
	/*
	pigment {
		colour Red
	}*/
}

#declare plaque=union {
	difference {
		box {
			<-81, 55, -9>
			<-79, 50, 9>
		}
		text {
			ttf
			"arial.ttf"
			"This bench is dedicated to the memory"
			.1, 0.052*x
			scale 0.85
			rotate y*90
			translate <-81.05, 53.5, 8>
		}
		text {
			ttf
			"arial.ttf"
			"of all the people who have died in"
			.1, 0.13*x
			scale 0.85
			rotate y*90
			translate <-81.05, 52.4, 8>
		}
		text {
			ttf
			"arial.ttf"
			"mysterious circumstances while sitting on it"
			.1, 0
			scale 0.85
			rotate y*90
			translate <-81.05, 51.3, 8>
		}
	}
	sphere {
		<-81, 50.5, -8.5>
		.1
	}
	sphere {
		<-81, 54.5, -8.5>
		.1
	}
	sphere {
		<-81, 50.5, 8.5>
		.1
	}
	sphere {
		<-81, 54.5, 8.5>
		.1
	}
	texture	{
		plaquetexture
	}
}		
	object {plaque}
	object {plaque rotate y*180}
	
}

