// ************************************************************************************************************************
// HF Man - Creates Man_Object centered at <0,0,0>
//    Input: Man_No, Images_On
// ************************************************************************************************************************
#declare Man_Scaling =
   transform {translate -0.5 rotate x*-90 scale <1.0,1,1.01> }
#declare Man_Texture =
      #if (Images_On)
         texture {
            pigment {image_map {
               #switch (Man_No)
                  #case (1) jpeg "_Man_01.jpg" #break
                  #case (2) jpeg "_Man_02.jpg" #break
               #end
               interpolate 2.0 map_type 0 
                  // filter all 0.95
                  }
               rotate x*90 transform Man_Scaling}
            finish {ambient 0.2 reflection 0.0 } }
      #else
         texture {pigment {color (Pink*.25+Orange*.25+Flesh*.5) } finish {ambient 1.0 reflection 0.0 } }
      #end
#declare Man_Object =
   height_field { 
      #switch (Man_No)
         #case (1) jpeg "_Man_01.jpg" #break
         #case (2) jpeg "_Man_02.jpg" #break
      #end
      smooth water_level 10/255
      transform Man_Scaling
      texture {Man_Texture}
      //texture {pigment {White filter 0.2} finish {ambient 1.0} }
      //pigment {White filter 0.2} finish {ambient 0.3 reflection 0.0 }
      // Keep in proportion to original image
      #switch (Man_No)
         #case (1) scale <109,320,10>*0.01 #break // "_Man_01.jpg" // Cowboy
         #case (2) scale <116,320,10>*0.01 #break // "_Man_02.jpg" // Victorian Woman's Ghost
      #end
   }
   
